Web Hosting by Netfirms | Free Domain Names by Netfirms

WebSite and Software Development

Home News Buiz Weather Games Developers Comix

Software & More

contact us

Xpounded Examine JFIF JPEG

Image Scripting: Examine JFIF file structure of JPEG Image

code is copyright Robert Spoons 2007 credit use Thanks.
Using VBS to evamine baseline JPEG image files...

This script shows how a baseline JPEG is stored in a JFIF file.

USE:

You use the script by dragging and dropping a baseline JPEG Image file onto it.
First the script will examine its own parent folder looking for a subfolder with the same name as the dropped file. If it can not find such a folder, it will create one.
Second, the script will do a simple analysis on the dropped image file and report its findings in a text file which it creates in the files (new) folder.

Built to read baseline JPEG JFIF files
The information for the algorithms abound on the net (google jfif) - the vbs implementaion is my own.

The markers this script will locate and report on are:

	(The 'Sample:' text is the result of a typical run)

	SOI		(FFD8) Start of image
	Sample:
	SOI Marker
			(Start Of Image Marker)
			* No Content *
			Start Byte: 1
			End Byte: 2

	APP0		(FFE0) Application data
	Sample:
	APP0 Marker
		(Application Data Segment)
		LengthOfSegment: 16
		Start Byte: 3
		End Byte: 20
		Version: 1.1
		Units: 1
		Xdensity: 72
		Ydensity: 72
		XThumb (Width): 0
		YThumb (Height): 0

	DQT		(FFDB) Quatization Table
	Sample:
	DQT Marker
		(Quantization Table Segment - QT Tables)
		LengthOfSegment: 67
		Start Byte: 21
		End Byte: 89
		Number Of QT Tables: 1

		Table ID: 0
		Precision: 0
		Table Data: 
		48, 53, 51, 52, 52, 52, 51, 53, 
		52, 52, 52, 53, 53, 53, 54, 55, 
		49, 56, 55, 55, 55, 55, 49, 49, 
		49, 57, 49, 49, 49, 49, 49, 49, 
		49, 49, 49, 49, 50, 50, 50, 49, 
		50, 50, 50, 49, 49, 50, 51, 50, 
		50, 50, 50, 51, 51, 51, 49, 50, 
		51, 51, 51, 51, 51, 50, 51, 51, 

	SOF0		(FFC0) Start of frame 0
	Sample:
	SOF0 Marker
		(Start Of Frame 0 Segment - Components Used By Id 1=Y, 2=Cb, 3=Cr)
		LengthOfSegment: 17
		Start Byte: 159
		End Byte: 177
		Data Precision: 8
		Y (Image Height): 197
		X (Image Width): 300
		NumberOfComponents: 3
		Component Data: 
		Component ID: 1
			Horiz Sample Factor: 3
			Vert Sample Factor: 3
			Quant Table (QT Table ID) To Use : 0
		Component ID: 2
			Horiz Sample Factor: 3
			Vert Sample Factor: 1
			Quant Table (QT Table ID) To Use : 1
		Component ID: 3
			Horiz Sample Factor: 3
			Vert Sample Factor: 1
			Quant Table (QT Table ID) To Use : 1

	DHT		(FFC4) Huffman table
	Sample:
	DHT Marker
			(Huffman Table Segment - HT Tables)
			LengthOfSegment: 28
			Start Byte: 178
			End Byte: 207
			Table Class: 0
			Table ID: 0
			total number of codes: 9
			CodeTable: 
			Code Length (Category): Number Of Codes (In Category): 
				Binary Code (For 8-Bit Lookup Symbol): 8-Bit LookUp Symbol (HEX)
			Code Length = 2 : # of Codes = 1 : 
				00: 00
			Code Length = 3 : # of Codes = 5 : 
				010: 03
				011: 04
				100: 05
				101: 06
				110: 07
			Code Length = 4 : # of Codes = 1 : 
				1110: 02
			Code Length = 5 : # of Codes = 1 : 
				11110: 01
			Code Length = 6 : # of Codes = 1 : 
				111110: 08


	DRI		(FFDD) Retart interval

	SOS		(FFDA) Start of scan
	Sample:
	SOS Marker
			(Start Of Scan Segment - Image Data starts immediatly after this header)
			LengthOfHeader: 12
			Start Byte: 373
			End Byte (Last Byte Of Header):386
			NumberOfComponentsInScan: 3
			Components 
				Component Selector: 1
					Td (HT Table ID For DC - class 0): 0
					Ta (HT Table ID For AC - class 1): 0
				Component Selector: 2
					Td (HT Table ID For DC - class 0): 1
					Ta (HT Table ID For AC - class 1): 1
				Component Selector: 3
					Td (HT Table ID For DC - class 0): 1
					Ta (HT Table ID For AC - class 1): 1
			StartOfSpectralSelection: 0
			EndOfSpectralSelection: 63
			Ah: 0
			Al: 0

	RST0 to RST7	(FFD0 to FFD7) Reset token
	JPG		(FFC8) Reserved for extensions
	DNL		(FFDC) Number of lines
	COM		(FFFE) Comments

	EOI		(FFD9) End of image
	Sample:
	EOI Marker
			(End Of Image Marker)
			* No Content *
			Start Byte: 8164
			End Byte: 8165

If the result looks cryptic to you, google a reference to the (JPEG) JFIF file structure.
Hope this helps someone starting their journey to understanding JPEG/JFIF structure and how to build a JPEG Decoder.
Almost forgot, the 'missing' part of this implementaion that would make this script a JPEG decoder (you know the part where the mcu's are decoded from the encoded image data bitstream and the huffman tables into 8x8 zigzag blocks that are dequantized, have the inverse discrete cosine transform (idct) applied, shited (128), and converted back to RGB) is avilable upon request.
toodles

Available REFS:
Graphics File Formats 2nd Edition. David C. Kay & John R. Levine
JPEG File Interchange Format. Version 1.02 Eric Hamilton
JPEG Standard ISO/IEC 10918-1
CCITT Rec T.81

An nice small intro to decoding jpeg: ImpulseAdventure - JPEG Huffman Coding Tutorial
when reading remember that the huffman table code for ac data is highbits = # of preceding 0's and lowbits = code category

Use the 1st 16 bytes of encoded image data returned by JpegMarkers.vbs to work through the real encoded image data on your own.

Requirements: Windows 98+, WSH 5.6+ (VBS), Image File in 24-bit non-compressed BMP format.

Tested on XP Home edition SP2, IE6 installed. (Not tested with IE7 installed)

Save this file to your system as JpegMarkers.vbs

Select All

'******************************************************************************
' By rdspoons
' Program Name
' Starts Here...
'
'JPEGMarkers reveals data inside JFIF header - creates a text report in (created) sub folder with same name as file
'basic - shows how jfif data is organized, how to get it and interpret it.

Dim g_args, WshShell, fso, g_msg, g_vbsCodePath
set WshShell = WScript.CreateObject("WScript.Shell")
desktop = WshShell.SpecialFolders("Desktop")
Set g_args = WScript.Arguments
Set fso = createObject("Scripting.FileSystemObject")
g_msg = "Problems. Now Closing"
g_vbsCodePath = desktop & "\SImages\vbsParts\"
'.............................................................
'Includes go here
'******************************************************************************
' General Script Methods
' Starts Here .....
'
'................................................................................
Function getArgs()
	Set a = WScript.Arguments
	gatArgs = a
	Set a = Nothing
End Function
'................................................................................
Function folderExists(sFolderPath)
	Dim bReturn
	bReturn =  fso.FolderExists(sFolderPath)
	folderExists = bReturn
End Function
'................................................................................
Function makeFolder(sPath)
	Dim objFolder
	Set objFolder = fSO.CreateFolder(sPath)
	makeFolder = objFolder
End Function
'................................................................................
Function getName(sPath)
	Dim g1, g2
	g1 = InStrRev(sPath,"\")
	If g1 > 0 Then
		sPath = Right(sPath,Len(sPath)-g1)
	End IF
	g2 = InStr(sPath,".")
	If g2 > 0 Then
		sPath = Left(sPath,g2-1)
	End If
	getName = sPath
End Function
'................................................................................
Function getFile(sPath)
	Dim g1
	g1 = InStrRev(sPath,"\")
	If g1 > 0 Then
		sPath = Right(sPath,Len(sPath)-g1)
	End IF
	getFile = sPath
End Function
'................................................................................
Function getPath(sPath)
	Dim g1
	g1 = InStrRev(sPath,"\")
	If g1 > 0 Then
		sPath = Left(sPath,g1)
	End If
	If Right(sPath,1) = "\" Then
		sPath = Left(sPath,Len(sPath)-1)
	End If
	getPath = sPath
End Function
'................................................................................
function getByteVal(ar, startByte,numBtyes)
	dim ret
	ret = 0
	d= 1
	for i = startByte to startByte + numBtyes - 1
		ret = ret + d * cint(asc(ar(i)))
		d = d*256
	next
	getByteVal = ret
end function
'................................................................................
Sub saveFile(path,sContent)
	Dim result
	Set result = fso.createTextFile(path,True)
	result.Write sContent
	result.Close
	Set result = Nothing
End Sub
'................................................................................
Function readFileIntoArray(path)
	Dim f,r(),counter1
	counter1=0
	Set f = fso.OpenTextFile(path, 1)
	Do until f.atendofstream
		counter1=counter1+1
		redim preserve r(counter1+1)
		r(counter1)=f.read(1)
	Loop	
	readFileIntoArray=r
	f.Close 
	Set f = Nothing
End Function
'................................................................................
Function saveFileFromArray(tname,r,newStuff)
	Dim result,s,gpos
	gpos=InstrRev(tname,".")
	tname = left(tname,gpos-1) & "_" & newStuff & right(tname,len(tname)-gpos+1)
	Set result = fso.createTextFile(tname,True)
	for i=0 to ubound(r)
		result.Write r(i)
	next
	result.Close
	Set result = Nothing
	saveFileFromArray = tname
End Function
'................................................................................
'IN: arr = image data array
'tries to get info about baseline jpeg file
'takes baseline jpeg file data and returns info about image structure back to user in text form
'used to examine strucure of jfif
'note lack of error control - add it if you want it.
'you can detect file type and abort if you want (no SOI, no JFIF0, etc = abort)
'Variables are pretty well documented trough nameing and comments
'global g_ptr is used to access the image data array arr
'functions ReadByte() and Read2Bytes() adjust the global g_ptr
'tmp_ptr is used to track the byte location of markers (points to 1st byte after 2-byte marker)
'finally, look to comments and imgtxt for more detail in particular sections
Dim g_ptr, tmp_ptr, iError
g_ptr = 1
Function DecodeJPEG(arr)  
	imgtxt = ""	
	Dim DQTable(4,65), Component(3,3), ScanComponent(3,2), DHTable(4,17), HuffmanTable(4,16)
	Dim huffSymbolTable(4,16,65536), huffBitsTable(4,16,65536)
	Dim LengthOfSegment, checkForMarker, marker, dqt_tableNumb, huff_table, BigestJ
	huff_table = 0

'Just comment out the imgtxt if you don't want the report
	'there's an imgtxt for each marker
	imgtxt = imgtxt & "NOTES:" & vbcrlf & _ 
		vbtab & "1) StartByte indicates the 1st byte of the respective 2 Byte Segment Marker" & vbcrlf & _
		vbtab & "2) Segment Lengths do not include the 2 Bytes of their Segment Marker" & vbcrlf & _
		vbtab & "3) Byte Data is 1-based (counting starts at 1, not 0)" & vbcrlf & _
		vbtab & "4) Jumps from EndByte to StartByte indicate ignored markers/data" & vbcrlf & vbcrlf

Do
    		Do
			marker = 0
			'Find marker	(standard says multiple FF bytes must be ignored)
			'looks for FF and if next byte is not 0 and its not FF then it might be a baseline marker
      			checkForMarker = ReadByte(arr)
      			if checkForMarker = 255 Then 
				marker = ReadByte(arr)
				if (marker=255) OR (marker=0) Then
					g_ptr = g_ptr - 1						'ignored, so reset 1 byte and continue
				Else 
					Exit Do
				End If
      			End If
 		Loop

'..........................................
		'................ SOI .....................
		'..........................................
		If marker=216 Then		'FFD8 : SOI
			tmp_ptr = g_ptr
	
			imgtxt = imgtxt & "SOI Marker" & vbcrlf & _
				vbtab & "(Start Of Image Marker)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
			'................ APPO ....................
			'..........................................
		ElseIf marker = 224 Then	'FFE0 : APP0	(Application Specific Data - JFIF Segment)
			tmp_ptr = g_ptr
			LengthOfSegment = Read2Bytes(arr)			'length (high byte, low byte), must be >= 16
			' JFIF/0 (4A, 46, 49, 46, 00)
			If (arr(g_ptr) <> "J") OR (arr(g_ptr+1) <> "F") OR (arr(g_ptr+2) <> "I") _
			OR (arr(g_ptr+3) <> "F") OR (asc(arr(g_ptr+4)) <> 0) Then
				DecodeJPEG = 3	'no jfif/0 text
				Exit Function
			End If
			g_ptr = g_ptr + 5						'directly adjust to jump past JFIF/0 text
			Version = ReadByte(arr) & "." & ReadByte(arr)	'major revision number, should be 1 (error otherwise)
											'minor revision number, should be 0..2 (try to decode reguardless)
			Units =  ReadByte(arr)					'units for x,y densities:			
     											'	0 = no units, x/y-density specify the aspect ratio instead
     											'	1 = x,y - density is pixels/inch
     											'	2 = x,y - density is pixels/cm
			Xdensity = Read2Bytes(arr)				'x density (high byte, low byte), should be <> 0
			Ydensity = Read2Bytes(arr)				'y density (high byte, low byte), should be <> 0
			XThumb = ReadByte(arr)					'thumbnail width (1 byte)
			YThumb = ReadByte(arr)					'thumbnail height (1 byte)
			'Ignore Thumb if it exists				'n bytes for thumbnail (RGB 24 bit), n = width*height*3
			'Should see a jump in adress for next marker if Thumb data exists

'Remarks:
  			'	If there's no 'JFIF'#0, or the length is < 16, then it is probably not
    			'	a JFIF segment and should be ignored.
  			'	Normally units=0, x-dens=1, y-dens=1, meaning that the aspect ratio is 1:1 (evenly scaled).
  			'	JFIF files including thumbnails are very rare, the thumbnail can usually be ignored.  
			'	If there's no thumbnail, then width=0 and height=0.
  			'	If the length doesn't match the thumbnail size, a warning may be printed, then continue decoding.

imgtxt = imgtxt & "APP0 Marker" & vbcrlf & _
				vbtab & "(Application Data Segment)" & vbcrlf & _
				vbtab & "LengthOfSegment: " & LengthOfSegment & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & _
				vbtab & "Version: " & Version & vbcrlf & _
				vbtab & "Units: " & Units & vbcrlf & _
				vbtab & "Xdensity: " & Xdensity & vbcrlf & _
				vbtab & "Ydensity: " & Ydensity & vbcrlf & _
				vbtab & "XThumb (Width): " & XThumb & vbcrlf & _
				vbtab & "YThumb (Height): " & YThumb & vbcrlf & vbcrlf

'..........................................
		'................ DQT .....................
		'..........................................
		ElseIf marker = 219 Then	'FFDB : DQT   (Quantization Table)
			'The location of QT tables can change from JFIF file to JFIF file
			'Some files may have multiple QT tables under 1 DQT marker.
			'Some Files may have multiple DQT makers.

tmp_ptr = g_ptr
			LengthOfSegment = Read2Bytes(arr)				'length (high byte, low byte)
			Do
				DQTable(dqt_tableNumb,0) = ReadByte(arr)
				'PT = ReadByte(arr)					'QT information (1 byte):
     												'bit 0..3: number of QT (0..3, otherwise error)
     												'bit 4..7: precision of QT, 0=8 bit, otherwise 16 bit
				For i = 1 To 64
					DQTable(dqt_tableNumb,i) = ReadByte(arr)	'n bytes QT, n = 64*(precision+1)
				Next
				dqt_tableNumb = dqt_tableNumb + 1
			Loop Until(g_ptr>=(tmp_ptr + LengthOfSegment))

'Remarks:
  			'	A single DQT segment may contain multiple QTs, each with its own information byte.
  			'	For precision=1 (16 bit), the order is high-low for each of the 64 words.

s=""
			for i = 0 To dqt_tableNumb-1
				s = s & vbcrlf & vbtab & "Table ID: " & Int(DQTable(i,0) AND 15) & vbcrlf & _
					vbtab & "Precision: " & Int(DQTable(i,0)/16) & vbcrlf & _
					vbtab & "Table Data: " & vbcrlf & vbtab
				For j = 0 To 63
					s = s & asc(DQTable(i,j)) & ", "
				Next
				s = s & vbcrlf
			Next

imgtxt = imgtxt & "DQT Marker" & vbcrlf & _
				vbtab & "(Quantization Table Segment - QT Tables)" & vbcrlf & _
				vbtab & "LengthOfSegment: " & LengthOfSegment & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & _
				vbtab & "Number Of QT Tables: " & dqt_tableNumb & vbcrlf & _
				s & vbcrlf & vbcrlf

'..........................................
		'................ SOF0 ....................
		'..........................................
		ElseIf marker = 192 Then	' FFC0 : SOF0
			'There will be only one Frame (Image) for baseline JPEG in a JFIF file.

tmp_ptr = g_ptr
			LengthOfSegment = Read2Bytes(arr)	'length (high byte, low byte), 8+components*3
			P = ReadByte(arr)				'data precision (1 byte) in bits/sample, usually 8 (12 and 16 not supported by most software)
			Y = Read2Bytes(arr)			'image height (2 bytes, Hi-Lo), must be >0 if DNL not supported
			X = Read2Bytes(arr)			'image width (2 bytes, Hi-Lo), must be >0 if DNL not supported

gwidth = X
			gheight = Y

NumberOfComponents = ReadByte(arr)	'- number of components (1 byte), usually 1 = grey scaled, 3 = color YCbCr or YIQ, 4 = color CMYK)
			For i = 0 To NumberOfComponents - 1
				'for each component: 3 bytes
				Component(i,0) = ReadByte(arr)	'ID component id (1 = Y, 2 = Cb, 3 = Cr, 4 = I, 5 = Q)
				Component(i,1) = ReadByte(arr)	'Horiz/Vert Sample Factor sampling factors (bit 0-3 vert., 4-7 hor.)
				Component(i,2) = ReadByte(arr)	'Quatization Table To Use quantization table number
			Next

'Remarks:
  			'	JFIF uses either 1 component (Y, greyscaled) or 3 components (YCbCr, sometimes called YUV, colour).

s = ""
			For i = 0 To NumberOfComponents - 1
				s = s & vbtab & "Component ID: " & Component(i,0)  & vbcrlf 
				s = s & vbtab & vbtab & "Horiz Sample Factor: " & Int(asc(Component(i,1))/16)  & vbcrlf 
				s = s & vbtab & vbtab & "Vert Sample Factor: " & Int(asc(Component(i,1)) AND 15) & vbcrlf 
				s = s & vbtab & vbtab & "Quant Table (QT Table ID) To Use : " & Component(i,2)  & vbcrlf 
			Next

imgtxt = imgtxt & "SOF0 Marker" & vbcrlf & _
				vbtab & "(Start Of Frame 0 Segment - Components Used By Id 1=Y, 2=Cb, 3=Cr)" & vbcrlf & _
				vbtab & "LengthOfSegment: " & LengthOfSegment & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & _
				vbtab & "Data Precision: " & P & vbcrlf & _
				vbtab & "Y (Image Height): " & Y & vbcrlf & _
				vbtab & "X (Image Width): " & X & vbcrlf & _
				vbtab & "NumberOfComponents: " & NumberOfComponents & vbcrlf & _
				vbtab & "Component Data: " & vbcrlf & vbcrlf & _
				s & vbcrlf

'..........................................
		'................ DHT .....................
		'..........................................
		ElseIf marker = 196 Then	' FFC4 : DHT
			'DHT non-SOF Marker - Huffman Table is required for decoding 
             	'the JPEG stream, when we receive a marker we load in first 
            	'the table length (16 bits), the table class (4 bits), table 
            	'identifier (4 bits), then we load in 16 bytes and each byte 
            	'represents the count of bytes to load in for each of the 16 
            	'bytes. We load this into an array to use later and move on 4 
			'huffman tables can only be used in an image.

'The location of HT tables can change from JFIF file to JFIF file
			'Some files may have multiple HT tables under 1 DHT marker.
			'Some Files may have multiple DHT makers.

tmp_ptr = g_ptr
			LengthOfSegment = Read2Bytes(arr)			'length (high byte, low byte)
			
			sh = ""
			'huff_table = 0
			Do
				'Reset huffBits() count variables
				lastHuff = 0
				lastCat = -1
				firstCat = -2

'DHTable will hold HT info in 0 and category counts in 1-16
				DHTable(huff_table,0) = ReadByte(arr)		'TcTh Tc=Table Class th=Table ID  HT information (1 byte):
     												'bit 0..3: number of HT (0..3, otherwise error)
     												'bit 4   : type of HT, 0 = DC table, 1 = AC table
     												'bit 5..7: not used, must be 0

For i = 1 To 16
					'16 bytes: number of symbols with codes of length 1..16, the sum of these
    					'bytes is the total number of codes, which must be <= 256
					DHTable(huff_table,i) = ReadByte(arr)	'Li # of Codes of Length i
				Next

n = 0
				ssh = vbtab & "Code Length (Category): Number Of Codes (In Category): " & vbcrlf & _
					vbtab & vbtab & "Binary Code (For 8-Bit Lookup Symbol): 8-Bit LookUp Symbol (HEX)" & vbcrlf & vbcrlf

For i = 1 To 16
					k = DHTable(huff_table,i)			'Vij Values for each code length
					n = n + k
					If k > 0 Then
						ssh = ssh & vbtab & "Code Length = " & i & " : # of Codes = " & k & " : " & vbcrlf 
					End If
					For j = 0 To k-1
						'n bytes: table containing the symbols in order of increasing code length
    						'(n = total number of codes)
						huffSymbolTable(huff_table,i,j) = ReadByte(arr)
						huffBitsTable(huff_table,i,j) = huffBits(i)
						ssh = ssh & vbtab & vbtab & huffBitsTable(huff_table,i,j) & ": " & Right("00" & Hex(huffSymbolTable(huff_table,i,j)),2) & vbcrlf
					Next
					If k > 0 Then
						ssh = ssh & vbcrlf 
					End If
				Next

'Remarks:
  				'	A single DHT segment may contain multiple HTs, each with its own
    				'	information byte.

sh = sh & vbtab & "Table Class: " & Int(DHTable(huff_table,0)/16) & vbcrlf & _
					vbtab & "Table ID: " & (DHTable(huff_table,0) AND 15) & vbcrlf & _
					vbtab & "total number of codes: " & n & vbcrlf & _
					vbtab & "CodeTable: " & vbcrlf & vbcrlf & ssh & vbcrlf

huff_table = huff_table + 1
			Loop until(g_ptr >(tmp_ptr + LengthOfSegment-1))

imgtxt = imgtxt & "DHT Marker" & vbcrlf & _
				vbtab & "(Huffman Table Segment - HT Tables)" & vbcrlf & _
				vbtab & "LengthOfSegment: " & LengthOfSegment & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf &  _
				sh & vbcrlf

'..........................................
		'................ DRI .....................
		'..........................................
		ElseIf marker = 221 Then	' FFDD : DRI
			'If no DRI then no RSTn (resets)

tmp_ptr = g_ptr
			LengthOfSegment = Read2Bytes(arr)			'length (high byte, low byte), must be = 4
			NumberOfMCU = Read2Bytes(arr)				'restart interval (high byte, low byte) in units of MCU blocks,
    											'meaning that every n MCU blocks a RSTn marker can be found.
    											'The first marker will be RST0, then RST1 etc, after RST7 repeating from RST0.

imgtxt = imgtxt & "DRI Marker" & vbcrlf & _
				vbtab & "(Define Restart Interval Segment - number of MCU)" & vbcrlf & _
				vbtab & "LengthOfSegment: " & LengthOfSegment & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & _
				vbtab & "NumberOfMCU: " & NumberOfMCU & vbcrlf & vbcrlf

'..........................................
		'................ SOS .....................
		'..........................................
		ElseIf marker = 218 Then	' FFDA : SOS
			'the start of the image area follows this header

tmp_ptr = g_ptr
			LengthOfHeader = Read2Bytes(arr)			'length (high byte, low byte), must be 6+2*(number of components in scan)
			NumberOfComponentsInScan = ReadByte(arr)		'number of components in scan (1 byte), must be >= 1 and <=4 (otherwise error), usually 1 or 3

For i=0 To NumberOfComponentsInScan - 1
				'for each component: 2 bytes
				ScanComponent(i,0) = ReadByte(arr)		'Component Selector component id (1 = Y, 2 = Cb, 3 = Cr, 4 = I, 5 = Q), see SOF0
				ScanComponent(i,1) = ReadByte(arr)		'TdTa Td=DCTableCode# Ta=ACTableCode#  Huffman table to use:
        										'		bit 0..3: AC table (0..3)
        										'		bit 4..7: DC table (0..3)
			Next
			
			'3 bytes to be ignored (???)
			Ss = ReadByte(arr)					'Ss Start Of Spectral Selection
			Se = ReadByte(arr)					'Se End Of Spectral Selection
			AhAl = ReadByte(arr)					'AhAl Ah=HighBitsSpectralSelection Al=LowBits (Must be 00)

'Remarks:
  			'	The image data (scans) is immediately following the SOS segment.

s=""
			For i = 0 To NumberOfComponentsInScan - 1
				s = s & vbtab & "Component Selector: " & ScanComponent(i,0) & vbcrlf
				s = s & vbtab & vbtab & "Td (HT Table ID For DC - class 0): " & Int(ScanComponent(i,1)/16) & vbcrlf
				s = s & vbtab & vbtab & "Ta (HT Table ID For AC - class 1): " & (ScanComponent(i,1) AND 15) & vbcrlf
			Next
			s = s & vbtab & "StartOfSpectralSelection: " & Ss & vbcrlf
			s = s & vbtab & "EndOfSpectralSelection: " & Se & vbcrlf
			s = s & vbtab & "Ah: " & Int(AhAl/16) & vbcrlf
			s = s & vbtab & "Al: " & (AhAl AND 15) & vbcrlf

imgtxt = imgtxt & "SOS Marker" & vbcrlf & _
				vbtab & "(Start Of Scan Segment - Image Data starts immediatly after this header)" & vbcrlf & _
				vbtab & "LengthOfHeader: " & LengthOfHeader & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte (Last Byte Of Header):" & (g_ptr-1) & vbcrlf & _
				vbtab & "NumberOfComponentsInScan: " & NumberOfComponentsInScan & vbcrlf & _
				vbtab & "Components " & vbcrlf & _
				vbtab & s & vbcrlf & vbcrlf & _
				"<Start of IMAGE DATA. UN-DECODED>" & vbcrlf & vbcrlf
			
			'First 16 bytes of data (Adjust, or remove as desired)
			imgtxt = imgtxt & "First 16 Bytes of Encoded Image Data shown Binary:" & vbcrlf
			for i = 1 to 16
				imgtxt = imgtxt & Dec2Bin(ReadByte(arr))
			next
			imgtxt = imgtxt & " ..." & vbcrlf & vbrclf

'..........................................
		'................ RST0 ....................
		'..........................................
		ElseIf marker = 208 Then	' FFD0 : RST0
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST0 Marker" & vbcrlf & _
				vbtab & "(Restart 0)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST1 ....................
		'..........................................
		ElseIf marker = 209 Then	' FFD1 : RST1
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST1 Marker" & vbcrlf & _
				vbtab & "(Restart 1)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST2 ....................
		'..........................................
		ElseIf marker = 210 Then	' FFD2 : RST2
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST2 Marker" & vbcrlf & _
				vbtab & "(Restart 2)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST3 ....................
		'..........................................
		ElseIf marker = 211 Then	' FFD3 : RST3
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST3 Marker" & vbcrlf & _
				vbtab & "(Restart 3)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST4 ....................
		'..........................................
		ElseIf marker = 212 Then	' FFD4 : RST4
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST4 Marker" & vbcrlf & _
				vbtab & "(Restart 1)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST5 ....................
		'..........................................
		ElseIf marker = 213 Then	' FFD5 : RST5
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST5 Marker" & vbcrlf & _
				vbtab & "(Restart 5)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST6 ....................
		'..........................................
		ElseIf marker = 214 Then	' FFD6 : RST6
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST1 Marker" & vbcrlf & _
				vbtab & "(Restart 6)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ RST7 ....................
		'..........................................
		ElseIf marker = 215 Then	' FFD7 : RST7
			tmp_ptr = g_ptr

imgtxt = imgtxt & "RST1 Marker" & vbcrlf & _
				vbtab & "(Restart 7)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ JPG .....................
		'..........................................
		ElseIf marker = 200 Then	' FFC8 : EOI
			tmp_ptr = g_ptr

imgtxt = imgtxt & "JPG Marker" & vbcrlf & _
				vbtab & "(Reserved for extensions)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ DNL .....................
		'..........................................
		ElseIf marker = 220 Then	' FFDC : DNL
			tmp_ptr = g_ptr

imgtxt = imgtxt & "DNL Marker" & vbcrlf & _
				vbtab & "(Define Number Of Lines)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf

'..........................................
		'................ COM .....................
		'..........................................
		ElseIf marker = 254 Then	' FFFE : COM
			tmp_ptr = g_ptr

'..........................................
		'................ EOI .....................
		'..........................................
		ElseIf marker = 217 Then	' FFD9 : EOI
			tmp_ptr = g_ptr
			imgtxt = imgtxt & vbcrlf & "..." & vbcrlf & "<End of IMAGE DATA. UN-DECODED>" & vbcrlf & vbcrlf & _
				"EOI Marker" & vbcrlf & _
				vbtab & "(End Of Image Marker)" & vbcrlf & _
				vbtab & "* No Content *" & vbcrlf & _
				vbtab & "Start Byte: " & (tmp_ptr-2) & vbcrlf & _
				vbtab & "End Byte: " & (g_ptr-1) & vbcrlf & vbcrlf
			Exit Do
		End If
	Loop
  	DecodeJPEG = imgtxt		'0	'jpgImage	'1
End Function
'................................................................................
'Used to get 16 bit values (2 bytes) from array - increments global array pointer
Function Read2Bytes(vs)
	Dim x
  	If (g_ptr+1) >= UBound(vs) Then
    		msgbox "Unexpected end of file"
    		read2bytes = -1
 	End If
  	x=asc(vs(g_ptr)) * 256 + asc(vs(g_ptr+1))
  	g_ptr = g_ptr + 2
  	read2bytes = x
End Function
'................................................................................
'Used to get 8 bit values (1 byte) from array - increments global array pointer
Function ReadByte(vs)
	Dim ret
  	If g_ptr >= UBound(vs) Then
    		msgbox "Unexpected end of file"
    		readbyte = -1
	End If
	ret = asc(vs(g_ptr))
	g_ptr = g_ptr + 1
  	readbyte = ret
End Function
'-------------------------------------------------------------
'Inverse Discrete Cosign Transform
'IN: s = 8x8 matrix
'takes in frequency data - returns spacial data
Function IDCT(s)
	Dim v,u,x,y
	Dim temp(8,8)
	Dim PI
	Pi = 3.1415926535897932384626433832795
	for v=0 To 8 
		for u=0 To 8 
			for y=0 To 8 
				for x=0 To 8 
					temp(v,u) = temp(v,u) + s(y,x) * cos((2*x+1)*u*PI/16.0) * cos((2*y+1)*v*PI/16.0)
				Next
			Next
		Next
	Next
	for v=0 To 8 
		for u=0 To 8 
			if v=0 Then temp(v,u) = temp(v,u)/sqr(2)
			if u=0 Then temp(v,u) = temp(v,u)/sqr(2)
			s(v,u) = Int(temp(v,u)/16+0.5)
		Next
	Next
	IDCT = s
End Function
'-------------------------------------------------------------
'Used as support for huffBits() - this is where the binary code string is made
'dont laugh too hard.
'IN: n = value to encode, l = total length of code string
'k is used to locate higest power of 2 that will go into n
'b pads left hand side to ensure length is l
Function Dec2Huff(n,l)
	Dim i, k, m, b
	k = 0
	m = n
	leading = true
	For i = 0 to n
		if(m < 2^i) Then
			k = i-1
			Exit For
		end if
	Next
	For i = k to 0 Step -1
		if(m>= 2^i) Then
			m = m - 2^i
			b = b & "1" 
		else
			b = b & "0"
		end if
	Next
	b = right(String(l,"0") & b,l)
	Dec2Huff = b
End Function
'-------------------------------------------------------------
'globals used in huffman table creation
Dim lastHuff , lastCat, firstCat
lastHuff = 0
lastCat = -1
firstCat = -2
'-------------------------------------------------------------
'Used to nake binary code for huffman table
'stop laughing
'IN: n1 = Catgerory (length of bits)
'Uses global firstCat to start code from zero
'Uses global lastCat to track category change and control lastHuff adjustment
'Uses global lastHuff as value of binary code
function huffBits(n1)
	dim ret
	ret = ""
	if firstCat = -2 then
		firstCat = n1
		lastCat = n1
	end if
	if lastCat<> n1 then
		lastHuff = lastHuff*2
	End If
	ret = Dec2Huff(lastHuff,n1)
	lastHuff = lastHuff + 1
	lastCat = n1
	huffBits = ret
end function
'-------------------------------------------------------------
'IN: n = decimal value
'returns binary string
Function Dec2Bin(n)
	Dim i, k, m, b
	k = 0
	m = n
	For i = 0 to n
		if(m < 2^i) Then
			k = i-1
			Exit For
		end if
	Next
	For i = k to 0 Step -1
		if(m>= 2^i) Then
			m = m - 2^i
			b = b & "1" 
		else
			b = b & "0"
		end if
	Next
	Dec2Bin = b
End Function
'-------------------------------------------------------------
'IN: val = binary code string
'returns decoded decimal value
function huffmanDCCode(val)
	dim ret, v1
	v1 = Bin2Dec(val)
	ret = 2^(Len(val)-1)
	if v1 >= ret Then
		ret = v1
	Else
		ret = -(2^(Len(val)))+1 + v1
	End If
	huffmanDCCode = ret
end function
'-------------------------------------------------------------
'IN: n = binary string
'returns decimal value
Function Bin2Dec(n)
	Dim i, k, ln
	k = 0
	ln = Len(n)
	For i = ln To 1 Step -1
		if mid(n, i,1) = "1" Then
			k = k + 2^(ln-i)
		end if
	Next
	Bin2Dec = k
End Function
'-------------------------------------------------------------
'Used in makeStream() to remove the 0 byte from F0 byte pairs
lastStreamByte = 0
'-------------------------------------------------------------
'grabs bytes from an image data array and converts the data into a biary string
'IN: vs = image array
' n = pointer to byte location in array
' m = number of bytes to try to convert
Function makeStream(vs,n,m)
	dim ret, streamByte
	ret = ""
	'if F0 is in stream, the 0 is a stuffed byte that must be removed
	for i=n to n+m
		if i<ubound(vs)-2 then
			streamByte = ReadByte(vs)
			If (lastStreamByte <> 255) AND (streamByte <> 0) Then
				ret = ret & Dec2Bin(streamByte)
				lastStreamByte = streamByte
			Else
				lastStreamByte = 0
			End If
		end if
	Next
	makeStream = ret
End Function
'-------------------------------------------------------------
' YOUR CODE GOES HERE
u = g_args.Count
dim qw()
If u > 0  Then
	WshShell.popup "Examine Baseline JPEG Structure",2
		nx = g_args(0)

n = nx
		gn = getName(n)
		n = nx
		gp = getPath(n)
		newpth = gp & "\" & gn

if Not folderExists(newpth) then
			makeFolder newpth
		end if
		
		n = nx
		newSaveFile = newpth & "\" & getFile(n)
		t = readFileIntoArray(nx)

WshShell.popup fp & vbcrlf & "Image:" & vbcrlf & nx & vbcrlf & "Size: " & ubound(t)-1 & " BYTES", 2
		Dim jp, gwidth,gheight

jp =  DecodeJPEG(t)

savefile newSaveFile & ".txt", "Image:" & vbcrlf & nx & vbcrlf & "Size: " & ubound(t)-1 & " BYTES" & vbcrlf & _
			"WIDTH:" & cstr(gwidth) & vbcrlf & "HEIGHT: " & cstr(gheight) & vbcrlf & vbcrlf & jp
		m = "Done" & vbcrlf
End If
WshShell.popup m

No HTML to View

- Copyright 2007 Xpounded -
All JS code developed by Xpounded is developed in RHSCoder.
All VBS code developed by Xpounded is developed in VBS QuickDev IDE, or RHSCoder.
Privacy Statement