Xpounded WMI-HTA RegExplorer

An example of the usefulness of WMI, VBScript, and HTA's

See Whats in Your Registry In a Safer Manner

To Use: Copy the code locally to your desktop and then double-click to run the application.

Things you can do...
Enter your favorite keys you want to quikly view in the 'fast' select box.

Add a Copy to Clipboard function for selcted keys.

Add a Create/Delete SubKey function for selcted keys. *

Add a Create/Change/Delete Value function for selcted keys. *

Add More Hives.

* = Intentionally left out to claim 'See Whats in Your Registry In a Safer Manner'.

(Target System: XP/2003/2000, IE6, WSH 5.6, WMI)

Save this file as regReader.hta Mention Us

Select All

<HTML>

<HEAD>
   <!-- 
	Made by Xpounded 2004 rdspoons@poncacity.net
	EnumSubkeys and EnumRegDataTypeAndName Adopted and Modified from MS WMI Examples
	Peruse the registry. Keep up on Whats Installed and Active, or just have a look.
	You can add you favorite keys to fast select below where it says ADD THEM HERE:

Tampering with your registry can cause irreperable damage to your system a fact 
	we are indeminifying ourselves against by including this disclosure.

Not scared? Good, On with the HTA...
   -->
   <TITLE>Registry Explorer</TITLE>
   <HTA:APPLICATION
   ID = "oRegExploreApp"
   APPLICATIONNAME = "RegExplore 2004"
   BORDER = "thick"
   CAPTION = "yes"
   ICON = "app.ico"
   SHOWINTASKBAR = "yes"
   SINGLEINSTANCE = "yes"
   SYSMENU = "yes"
   WINDOWSTATE = "normal"
   SCROLL = "yes"
   SCROLLFLAT = "yes"
   VERSION = "1.0"
   INNERBORDER = "yes"
   SELECTION = "no"
   MAXIMIZEBUTTON = "yes"
   MINIMIZEBUTTON = "yes"
   NAVIGABLE = "yes"
   CONTEXTMENU = "yes"
   BORDERSTYLE = "normal"
   >
<script language="VBScript">
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Dim ChosenHive
Dim Hives(2)
Hives(0)="HKEY_CURRENT_USER"
Hives(1)="HKEY_LOCAL_MACHINE"
Dim HivesValue(2)
HivesValue(0)=HKEY_CURRENT_USER
HivesValue(1)=HKEY_LOCAL_MACHINE
Function EnumSubkeys(strKeyPath)
	resdiv2.innerText=""
	On Error Resume Next
	ChosenHive = hive.value
	Dim ret1
	Dim ret01
	ret1 = ""
	ret01="[" & Hives(ChosenHive) & "\" & strKeyPath & "]"
	resdiv01.innerHTML = ret01
	resdiv02.innerHTML = ""
	ret1=ret1 & "<table><tr><td><b>SubKey</b></td><td><b>Explore Deeper</b></td></tr>"
	strComputer = "."
	Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
		strComputer & "\root\default:StdRegProv")
	objReg.EnumKey HivesValue(ChosenHive), strKeyPath, arrSubKeys
	For Each Subkey in arrSubKeys
		ret1=ret1 & "<tr><td style='color:navy;cursor:hand;' onclick='showVals(" & chr(34) & strKeyPath & "\" & Subkey & chr(34) & ")'><u>"
    		ret1 = ret1 & Subkey  & "</u></td><td><button onclick='javascript:resdiv1.innerHTML=EnumSubkeys(" & chr(34) & replace(strKeyPath,"\","\\") & "\\" & Subkey & chr(34) & ");regin.value=" & chr(34) & replace(strKeyPath,"\","\\") & "\\" & Subkey & chr(34) & ";addNode(regin.value);'>DIG</button>" & strKeyPath & "\" & Subkey & "</td></tr>"
	Next
	ret1=ret & vbcrlf & ret1 & "</table>"
	On Error GoTo 0
	If Err<>0 Then msgbox Err.Number & vbcrlf & Err.Description,vbokonly,"Error"
	EnumSubkeys = ret1
End Function
Function EnumRegDataTypeAndName(strKeyPath)
	On Error Resume Next
	Dim ret
	Const REG_SZ = 1
	Const REG_EXPAND_SZ = 2
	Const REG_BINARY = 3
	Const REG_DWORD = 4
	Const REG_MULTI_SZ = 7
	strComputer = "."
	ChosenHive = hive.value
	resdiv02.innerHTML = "<b>(KEY)</b><br><font size=-1>" & Hives(ChosenHive) & "\" & strKeyPath & "</font>"
	Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
	objReg.EnumValues HivesValue(ChosenHive), strKeyPath, arrEntryNames, arrValueTypes
	ret="<table><tr><td><b>Entry Name: </b></td><td><b>Data Type: </b></td><td><b>Value: </b></td><tr>"	
	For i=0 To UBound(arrEntryNames)
		ret = ret & "<tr><td valign='top'>" & arrEntryNames(i) & "</td>"
 		Select Case arrValueTypes(i)
 			Case REG_SZ
				ret = ret &  "<td valign='top'>String</td>"
 				objReg.GetStringValue HivesValue(ChosenHive), _
 					strKeyPath, arrEntryNames(i),strValue
 				ret = ret &  "<td>" & strValue & "</td>"
 			Case REG_EXPAND_SZ
				ret = ret & "<td valign='top'>Expanded String</td>"
 				objReg.GetExpandedStringValue HivesValue(ChosenHive), _
 					strKeyPath, arrEntryNames(i), estrValue
				ret = ret & "<td valign='top'>" & estrValue & "</td>"
 			Case REG_BINARY
				ret = ret &  "<td valign='top'>Binary</td>"
 				objReg.GetBinaryValue HivesValue(ChosenHive), _
 					strKeyPath, arrEntryNames(i),arrValue
				ret = ret &  "<td>"
 				For Each byteValue in arrValue
					ret = ret &   byteValue & " "
 				Next
				ret = ret & "</td>"
 			Case REG_DWORD
				ret = ret & "<td valign='top'>DWORD</td>"
 				objReg.GetDWORDValue HivesValue(ChosenHive), _
 					strKeyPath, arrEntryNames(i),dwValue
				ret = ret & "<td>" & dwValue & "</td>"
 			Case REG_MULTI_SZ

ret = ret & "<td valign='top'>Multi String</td>"
 				objReg.GetMultiStringValue HivesValue(ChosenHive), _
 					strKeyPath, arrEntryNames(i),arrValues
				ret = ret &  "<td>"
 				For Each strValue in arrValues
					ret = ret & strValue & " "
 				Next
				ret = ret & "</td>"
 		End Select
		ret = ret & "</tr>"
	Next
	ret = ret & "</table>"
	On Error GoTo 0
	If Err<>0 Then msgbox Err.Number & vbcrlf & Err.Description,vbokonly,"Error"
	EnumRegDataTypeAndName = ret
End Function

Sub ShowVals(strHKPath)
	strHTML = EnumRegDataTypeAndName(strHKPath)
	resdiv2.innerHTML = strHTML
End Sub

Sub window_onload
	window.resizeTo 790,550
	window.moveTo 0,0
End Sub
Sub btn1_onclick
	strHKPath=regin.value
	strHTML = EnumSubkeys(strHKPath)
	resdiv1.innerHTML = strHTML
	addNode(regin.value)
End Sub

'History Emmulation
Dim nodes()
Dim curNode
Dim maxNodes
curNode = -1
Sub historyClick
	strHKPath=regin.value
	strHTML = EnumSubkeys(strHKPath)
	resdiv1.innerHTML = strHTML
End Sub
Sub addNode(data)
	curNode = curNode + 1
	ReDim Preserve nodes(curNode + 1)
	nodes(curNode)=data
	maxNodes = curNode
End Sub
Sub GoForward
	If curNode < maxNodes Then
		curNode = curNode + 1
	End If
	regin.value=nodes(curNode)
	historyClick
End Sub
Sub GoBack
	If curNode > 0 Then
		curNode = curNode - 1
	End If
	regin.value=nodes(curNode)
	historyClick
End Sub
Sub fast_onchange()
	regin.value = fast.value
End Sub
</SCRIPT>
</HEAD>
<BODY>
<button onclick="javascript:GoBack()"><</button> 
<button onclick="javascript:GoForward()">></button> 
<b>Subkey to Explore:
<span width="200">

<select id="fast">
	<option value="SOFTWARE\Microsoft\Windows\CurrentVersion">SOFTWARE\Microsoft\Windows\CurrentVersion</option>
	<option value="SOFTWARE\Microsoft\Windows\CurrentVersion\Shell Extensions">SOFTWARE\Microsoft\Windows\CurrentVersion\Shell Extensions</option>
	<option value="Software\Microsoft\Internet Explorer">Software\Microsoft\Internet Explorer</option>
</select>
</span>

<br>
<select id="hive">
<option value=0>HKEY_CURRENT_USER</option>
<option value=1 selected>HKEY_LOCAL_MACHINE</option>
</select>\</b><input id="regin" size="60" value="Software\Microsoft\Internet Explorer\Extensions">
<button id="btn1">Explorer</button>
<hr>
<DIV ID="resdiv01"></DIV>
<DIV ID="resdiv1" style="position:relative;width:100%;height:48%;overflow:auto"></DIV>
<hr>
<DIV ID="resdiv02"></DIV>
<DIV ID="resdiv2" style="position:relative;width:100%;height:26%;overflow:auto"></DIV>
</BODY>
</HTML>

No HTML to View

- Copyright 2004 Xpounded -
All JS code developed by Xpounded is developed in RHSCoder.
All VBS code developed by Xpounded is developed in VBS QuickDev IDE, or RHSCoder.
Privacy Statement
Feedback